<!--#include file="setting/conn.asp"-->
<%
Dim comeurl
Dim jintong(1,0)
comeurl = Request.ServerVariables("HTTP_REFERER")
Errmsg=SoonBiz.FilterJS(Trim(Request.QueryString("errmsg")))

If IsNumeric (Errmsg)  Then
	ErrMsg=CLng(ErrMsg)
	GetErrMsg()
Else
	Errmsg=SoonBiz.FilterJS(Trim(Request.QueryString("errmsg")))
End If

If InStr(comeurl,"user_")>0 Or InStr(comeurl,"admin_")>0 Or Len(comeurl)=0 Or Instr(comeurl,"operate")>0 Then
	Dim fuyou
	'SoonBiz.topplus="<style type=""text/css"">.main{width:75%;}</style>"
	SoonBiz.AdHead()
	If len(comeurl) > 0 Then
		fuyou = "<a href=""javascript:history.back(1)"" > 返回上一页</a>&nbsp;&amp;&amp;&nbsp;<a href=""javascript:window.close()"">关闭窗口</a>"
	Else
		fuyou = "<a href="""& webdir &"index.asp"">返回首页</a>&nbsp;&amp;&amp;&nbsp;<a href=""javascript:window.close()"">关闭窗口</a>"
	End If

	Response.Write "<div class='msgbox'>"
	Response.Write "	<h1>错误信息</h1>"
	Response.Write "	<ul>"&errmsg&"</ul>"
	Response.Write "	<div class=""back"">"& fuyou &"</div>"
	Response.Write "</div>"
	SoonBiz.adfoot
Else
	jintong(0,0) = "错误提示"
	jintong(1,0) = "#"
	SoonBiz.title="错误提示"

	htmlstr = SoonBiz.Tp(0,pn,"index")
	htmlstr = Replace(htmlstr,"{$navstate}",SoonBiz.getnavstate(jintong))
	htmlstr = Replace(htmlstr,"{$content}",Errmsg)
	htmlstr = Replace(htmlstr,"{$comeurl}",Request.ServerVariables("HTTP_REFERER"))

	htmlstr = Replace(htmlstr,"{$url}","javascript:history.back(1)") & "</div>" '<syl></div>结束head中的main<by syl>
	htmlstr = SoonBiz.huiqiaoHtml(htmlstr)
	SoonBiz.endhtml
End If
setallnothing

Sub GetErrMsg()
	Select Case ErrMsg
		Case 1000
			ErrMsg=""&_
			"<li>本操作只对会员开放,请登录后操作.</li>"&_
			"<li><a href='login.asp?act=login'>点击这里登录</a></li>"&_
			"<li><a href='login.asp'>点击这里注册为新会员</a></li>"
		Case 1013 : ErrMsg="<li>本操作有权限设置,您没有足够的权限</li>"
		Case 1017 : ErrMsg="<li>ID对应的用户组不存在或已经删除</li>"
		Case 1018 : ErrMsg="<li>您所查询或编辑的记录不存在或已被删除</li>"
		Case 1019 : ErrMsg="<li>分类ID不存在或已删除</li>"
		Case 1020 : ErrMsg="<li>您不是管理员</li>"
		Case 1021 : ErrMsg="<li>请不要在"& reposttime &"秒内重复提交</li>"
		Case 1022 : ErrMsg="<li>非法操作</li>"
		Case 1030 : ErrMsg="<li>请登录后操作</li>"
		Case 2004 :	ErrMsg="<li>认证码错误,如果确认输入的注册码没有问题,请刷新可能是认证码失效,请点击认证码刷新数字</li>"
		Case 3000
			ErrMsg = ""&_
			"<li>您不是管理员</li>"&_
			"<li>请按如下方法登录后台管理: <p>a.在前台登录 </p><p>b.登录成功后显示管理中心登录入口(此入口仅对管理员显示) </p><p>c.点击""进入网站管理中心(仅对管理员可见)"",输入管理员密码</p></li>"&_
			"<li><a href='login.asp?act=login'>点击这里登录前台</a></li>"
		Case 4000 : ErrMsg="<li>服务器不支持CreatePreviewImage组件</li>"
		Case 4010 : ErrMsg="<li>服务器不支持AspJpeg组件</li>"
		Case 4020 : ErrMsg="<li>服务器不支持SoftArtisans ImgWriter组件</li>"
		Case Else :	ErrMsg="<li>未知错误</li>"

	End Select
	'ErrMsg=ErrMsg & "(Errocde:"&Trim(Request.QueryString("ErrMsg"))&")"
End Sub
%>